# Read a mesh cylinder and reconnect Delaunay
#
# use connect to create nice Delaunay
# point distribution as well as possible

######################################
read / avs / cylinder.inp / mo    

# information about input mesh
cmo printatt mo -xyz- minmax
quality

# copy the points into a new mesh object
cmo create cmotet///tet                                                         
copypts/cmotet/mo                                                               
cmo delete mo

# set mesh attributes to initial values
cmo/select cmotet                                                               
cmo/setatt/cmotet/itetclr/1
cmo/setatt/cmotet/imt/1 0 0/1                                                   
cmo/setatt/cmotet/itp/1 0 0/0                                                   

# remove duplicate points if they exist
filter/1 0 0                                                                    
rmpoint/compress                                                                

######################################
# connect the points using Delaunay criteria
connect noadd                                                                   
resetpts/itp                                                                    
quality                                                                         

######################################
# Write fehm, avs, and gmv format files
dump fehm tet_connect cmotet ascii  
dump gmv tet_connect.gmv cmotet
dump avs2 tet_connect.inp cmotet 1 1 0 0

# Write mesh object information
cmo status cmotet
cmo printatt cmotet -all- minmax

# Check for negative coupling coefficients
# Check to see if any are on inside of mesh
cmo select cmotet
quality

# if ncoef > 0 then there are neg ccoefs
pset ncoef attribute ccoef 1,0,0 lt -0.001

# find points with point typ set to outside
pset pout attribute itp 1,0,0 eq 10.
pset pin not pout

# if pBAD has 0 POINTS then neg ccoefs are on outside
pset pBAD inter pin ncoef


finish