# xyclip_Top_ill01.inp
#  aquifer Pennsylvanian-Mississippian Sandstones
# xyclip_Top_ill06b.inp
#  confining New Albany Shale
# xyclip_Top_ill06a.inp
#  aquifer Devonian Carbonates
# xyclip_Top_ill06.inp
#  confining Maqoketa Shale
# xyclip_Top_ill07.inp
#  aquifer Ordivician Carbonate
# xyclip_Top_ill10.inp
#  confining Eau Claire Shale
# xyclip_Top_ill11.inp
#  aquifer Mt Simon Sandstone
# xyclip_Mt_Simon_bottom.inp 
#
#
# Make the Eau Claire equal to Mt Simon top + 65
#
# V02 - limit the Eau Claire thickness to 300m max
#
read / avs / xyclip_Mt_Simon_bottom.inp / mo1
read / avs / xyclip_Top_ill11.inp / mo2
read / avs / xyclip_Top_ill10.inp / mo3
read / avs / xyclip_Top_ill07.inp / mo4
read / avs / xyclip_Top_ill06.inp / mo5
read / avs / xyclip_Top_ill06a.inp / mo6
read / avs / xyclip_Top_ill06b.inp / mo7
read / avs / xyclip_Top_ill01.inp / mo8
#
# Truncate layers by setting z to z(mo8) if z is greater than mo8
#
define / MOTRUNC / mo8

define / MONAME / mo1
infile truncate_layers.mlgi
define / MONAME / mo2
infile truncate_layers.mlgi
define / MONAME / mo3
infile truncate_layers.mlgi
define / MONAME / mo4
infile truncate_layers.mlgi
define / MONAME / mo5
infile truncate_layers.mlgi
define / MONAME / mo6
infile truncate_layers.mlgi
define / MONAME / mo7
infile truncate_layers.mlgi


#
# Set Eau Claire
#
define / MONAME / mo1
define / M1 / mo1
define / M2 / mo2
define / M3 / mo3
infile add_att_copy_att.mlgi
#
# If Eau Claire thickness is >300 set it to 300
#
cmo / select / MONAME
pset / p_gt300 / attribute / z_cu_isopach / 1 0 0 / 300.0 / gt
cmo / setatt / MONAME / z_cu_isopach / pset get p_gt300 / 300.0
#
# Since the thickness of the Eau Claire has changed, reset z_cu_top to
# reflect new thickness. 
# z_top = z_bottom + thickness
#
math / add / MONAME / z_cu_top / 1 0 0 / &
             MONAME / z_cu_bot / MONAME / z_cu_isopach

define / MONAME / mo3
define / M1 / mo3
define / M2 / mo4
define / M3 / mo5
infile add_att_copy_att.mlgi

define / MONAME / mo5
define / M1 / mo5
define / M2 / mo6
define / M3 / mo7
infile add_att_copy_att.mlgi
#
# Special case
# There is no confining unit mo9
#
define / MONAME / mo7
define / M1 / mo7
define / M2 / mo8
define / M3 / mo8
infile add_att_copy_att.mlgi

dump / quads_w_isopachs_1_msss.inp / mo1
dump / quads_w_isopachs_2_orcarb.inp / mo3
dump / quads_w_isopachs_3_dsss.inp / mo5
dump / quads_w_isopachs_4_pmss.inp / mo7

dump / quads_w_isopachs_1_msss.gmv / mo1
dump / quads_w_isopachs_2_orcarb.gmv / mo3
dump / quads_w_isopachs_3_dsss.gmv / mo5
dump / quads_w_isopachs_4_pmss.gmv / mo7
#
# Now figure out which elements to delete based on:
# If all 4 nodes of a quad z_cu_isopach = 0.0
# AND
# If all 4 nodes of a quad z_aq_isopach = 0.0
# THEN
# Remove the element
#
cmo / select / mo1
infile delete_elem_mod_att.mlgi
dump / isopachs1_msss.inp / mo1
dump / isopachs1_msss.gmv / mo1

cmo / select / mo3
infile delete_elem_mod_att.mlgi
dump / isopachs2_ordcarb.inp / mo3
dump / isopachs2_ordcarb.gmv / mo3

cmo / select / mo5
infile delete_elem_mod_att.mlgi
dump / isopachs3_dsss.inp / mo5
dump / isopachs3_dsss.gmv / mo5

cmo / select / mo7
infile delete_elem_mod_att.mlgi
dump / isopachs4_pmss.inp / mo7
dump / isopachs4_pmss.gmv / mo7
##########################################
# In order to run stack the above
# infile delete_elem_mod_att.mlgi
# should be commented out since the stack command
# counts on all surfaces having the same footprint.
#
# The stack commands below are run to QA the surfaces
# and check things. The output produced is not required.
#
finish
##########################################

#
# Stack up the layers
#
# Compute layer elevations from isopach thickness
#
cmo / copyatt / mo1 / mo1 / zic / z_aq_bot
dump / avs / L00.inp / mo1 / 1 1 0 0
math / add / mo1 / zic / 1 0 0 / mo1 / zic / mo1 / z_aq_isopach
dump / avs / L01.inp / mo1 / 1 1 0 0
math / add / mo1 / zic / 1 0 0 / mo1 / zic / mo1 / z_cu_isopach
dump / avs / L02.inp / mo1 / 1 1 0 0

define / MO / mo3
cmo / copyatt / MO / MO / zic / z_aq_bot
dump / avs / L02a.inp / MO / 1 1 0 0
math / add / MO / zic / 1 0 0 / MO / zic / MO / z_aq_isopach
dump / avs / L03.inp / MO / 1 1 0 0
math / add / MO / zic / 1 0 0 / MO / zic / MO / z_cu_isopach
dump / avs / L04.inp / MO / 1 1 0 0

define / MO / mo5
cmo / copyatt / MO / MO / zic / z_aq_bot
dump / avs / L04a.inp / MO / 1 1 0 0
math / add / MO / zic / 1 0 0 / MO / zic / MO / z_aq_isopach
dump / avs / L05.inp / MO / 1 1 0 0
math / add / MO / zic / 1 0 0 / MO / zic / MO / z_cu_isopach
dump / avs / L06.inp / MO / 1 1 0 0

define / MO / mo7
cmo / copyatt / MO / MO / zic / z_aq_bot
dump / avs / L06a.inp / MO / 1 1 0 0
math / add / MO / zic / 1 0 0 / MO / zic / MO / z_aq_isopach
dump / avs / L07.inp / MO / 1 1 0 0
math / add / MO / zic / 1 0 0 / MO / zic / MO / z_cu_isopach
dump / avs / L08.inp / MO / 1 1 0 0

cmo create cmo_stack
stack/layers/avs &
L00.inp 1 0 &
L01.inp 2 0 &
L02.inp 3 0 &
L03.inp 4 0 &
L04.inp 5 0 &
L05.inp 6 0 &
L06.inp 7 0 &
L07.inp 7 0 truncate 8
stack/fill/cmofill/cmo_stack/
dump / gmv  / stack_fill.gmv / cmofill
cmo/addatt/cmofill/ volume / evol
dump / gmv  / stack_fill.gmv / cmofill
finish