#################################
#
# Make FULL BOX 
#
define X0 0. 
define X1 1000. 

define Y0 0. 
define Y1 1000. 

define Z0 0.
define Z1 600.

define NX 41 
define NY 41
define NZ 25
#
# For top cutout for slope 
define Xcut 300.
define Zcut 550.
#
#
#######################################
#  Create the brick mesh
#  We will use all but the line boundary
#  and top area below boundary
#  for the points of the mesh
#######################################

# evenly space points along x,y and z axis
cmo/create/mohex///hex
createpts/brick/xyz/NX NY NZ /X0 Y0 Z0 / X1 Y1 Z1 / &
       1,1,1/ 1,1,0/ 1. 1. 1. 
  cmo/setatt/mohex/imt1/1,0,0/1
  cmo/setatt/mohex/itetclr/1,0,0/1
  filter 1,0,0
  rmpoint compress
  resetpts itp

# cut out the place where the slope will go
cmo select mohex
pset/pxduds/attribute xic/1,0,0/ gt Xcut
pset/pzduds/attribute zic/1,0,0/ gt Zcut
pset/pduds/  inter pxduds pzduds
  eltset/eduds/inclusive pset,get,pduds
  cmo setatt mohex itetclr eltset,get,eduds 2
  dump gmv tmp_box_full.gmv mohex

cmo copy motop mohex 
cmo printatt mohex itetclr minmax
cmo printatt motop itetclr minmax
cmo select mohex
rmmat 2 
rmpoint compress
resetpts itp

cmo setatt mohex ipolydat no
dump gmv hex_base.gmv mohex
dump avs hex_base.inp mohex

# write the top part that was cut out
cmo select motop
eltset/e1/ itetclr eq 1
rmpoint element eltset,get,e1
rmpoint compress
resetpts itp

dump gmv hex_top.gmv motop
dump avs hex_top.inp motop

finish