# write FEHM files with imt set to zones 

read avs tet_final.inp mo
quality
cmo printatt mo -xyz- minmax

cmo / select / mo

# PLANES for fault 
# 800 to min top x 818.75 and 825
surface / sleft / intrface / plane / &
680.0 0. 0. / 800.0 1000.0 550.0 / 800.0 0.0 550.0

#  700.0 0. 0. / 820.0 1000.0 550.0 / 820.0 0.0 550.0 
surface / sright / intrface / plane / &
   710.0 0. 0. / 830.0 1000.0 550.0 / 830.0 0.0 550.0 

# BOX for repository middle at 300. (200x200x20)
# choose height to include 20m at resolution 3.125m
# 300 middle, z min 290.625 max 309.375 

define XMIN 100.
define XMAX 300.
define YMIN 400.
define YMAX 600.
define ZMIN 287.
define ZMAX 313.
define ZMIN 290.
define ZMAX 310.

# create outside node attributes
dump zone_outside tmp mo keepatt

#############################################
# Set the zones for FEHM files 
cmo select mo

# set all node imt and element itetclr to 5
cmo setatt mo imt 5
cmo setatt mo itetclr 5

# set all top nodes to 1 and this will be overwritten by top zone 2 
pset / pzone1 / attribute top / 1,0,0 / eq 1
eltset ezone1 inclusive pset,get,pzone1
  cmo / setatt / mo / imt / pset get pzone1 / 1
  cmo   setatt   mo   itetclr eltset,get,ezone1 1

# set top section right to 2
pset / pzone2 / attribute / xic / pset get pzone1 / ge / 700.0
eltset ezone2 inclusive pset,get,pzone2
  cmo setatt mo imt pset,get,pzone2 2
  cmo setatt mo itetclr eltset,get,ezone2 2

# set repository box shape to 3
pset/pbox/geom/xyz/1,0,0/ XMIN YMIN ZMIN / XMAX YMAX ZMAX
eltset/ebox/exclusive/pset,get,pbox
  cmo setatt mo imt pset,get,pbox 3
  cmo setatt mo itetclr eltset,get,ebox 3
  dump gmv tmp.gmv mo 

# set fault imt to 4
# set last so overwrite the nodes set to top
region / rflt / ge sleft and le sright
pset / pflt / region / rflt
eltset / eflt / exclusive / pset get pflt
  cmo / setatt / mo / imt / pset get pflt / 4
  cmo / setatt / mo / itetclr / eltset get eflt / 4

resetpts itp
cmo setatt mo ipolydat no
dump gmv tet_final_zones.gmv mo
dump avs tet_final_zones.inp mo

# do some FEHM preparation and checking
cmo/addatt/mo/matclr/vint/scalar/nelements////0
cmo/copyatt/ mo mo /matclr itetclr
cmo setatt mo itetclr 1
filter 1,0,0
rmpoint compress
resetpts itp
quality

* Must be single defined mesh
cmo select mo
resetpts/parent
rmpoint compress
cmo status mo brief

dump fehm tet mo
dump gmv tet_final_ccoef.gmv mo 

quality
cmo printatt mo -all- minmax

finish