# Create the top and bottom piece for mesh

#################################
# Extents for full box
#
define X0 0. 
define X1 1000. 
define Y0 0. 
define Y1 1000. 
define Z0 0.
define Z1 600.

# Resolution for full box 25m
define NX 41 
define NY 41
define NZ 25
# Resolution for full box 50m
define NX 21 
define NY 21
define NZ 13
#
# For top cutout for slope 
# Include a buffer of 25m elements
# Do not include refined fault with top
define Xcut  250.
define Xcut2 700.
define Zcut  500.
define Zcut2 550.
#
#
#######################################
# Make BASE PIECE 
#  Create the brick mesh
#  We will use all but the line boundary
#  and top area below boundary
#  for the points of the mesh
#######################################

# evenly space points along x,y and z axis
cmo/create/mohex///hex
createpts/brick/xyz/NX NY NZ /X0 Y0 Z0 / X1 Y1 Z1 / &
       1,1,1/ 1,1,0/ 1. 1. 1. 
  cmo/setatt/mohex/imt1/1,0,0/1
  cmo/setatt/mohex/itetclr/1,0,0/1
  filter 1,0,0
  rmpoint compress
  resetpts itp

# cut out the place where the slope will go
cmo select mohex
pset/pxduds/attribute xic/1,0,0/  gt Xcut
pset/px2duds/attribute xic/1,0,0/ lt Xcut2
pset/pzduds/attribute zic/1,0,0/  gt Zcut
pset/pduds/  inter pxduds px2duds pzduds
  eltset/eduds/inclusive pset,get,pduds
  cmo setatt mohex itetclr eltset,get,eduds 2
  dump gmv tmp_box_full.gmv mohex

rmpoint element eltset,get,eduds
rmpoint compress
resetpts itp

# remove base top that will align with top slope
cmo select mohex
pset/pz2/attribute zic/1,0,0/ gt Zcut2
pset/px2/attribute xic/1,0,0/ gt Xcut2
pset/pduds2/ inter pz2 px2
  eltset/eduds2/inclusive pset,get,pduds2

rmpoint element eltset,get,eduds2

cmo setatt mohex ipolydat no
dump gmv hex_base.gmv mohex
dump avs hex_base.inp mohex

#######################################
# Make  TOP PIECE 
# This is from the tet mesh 25m version
# make sure tip near x=700 is kept

read avs tet_top_25m.inp motop
 cmo printatt motop -xyz- minmax

cmo select motop
pset/px/attribute xic/1,0,0/  ge Xcut
pset/px2/attribute xic/1,0,0/ lt 701. 
pset/pz/attribute zic/1,0,0/  ge Zcut
pset/pkeep/  inter px px2 pz
pset/pduds/ not pkeep
  eltset/eduds/inclusive pset,get,pduds
  cmo setatt motop itetclr eltset,get,eduds 2
  dump gmv tmp_box_full.gmv motop

cmo select motop
rmpoint element eltset,get,eduds
rmpoint compress
resetpts itp

cmo setatt motop itetclr 1
cmo setatt motop imt 1
cmo setatt motop ipolydat no

dump gmv tet_top.gmv motop
dump avs tet_top.inp motop

###
# merge for viewing

addmesh/append/ mov / mohex motop
cmo setatt mov ipolydat no
dump gmv merge_base_top.gmv mov

finish