****************************** 
* 
* Carl W. Gable
* gable@lanl.gov
* LaGriT Control File
* http://lagrit.lanl.gov
* http://meshing.lanl.gov
* 
****************************** 
*
* Compute the various tet quality measures
*
* Minimum Dihedral Angle, (degree)
cmo / addatt / MO_NAME / ang_mind / a_mind
* Minimum Dihedral Angle, (radian)
cmo / addatt / MO_NAME / ang_minr / a_minr
* Maximum Dihedral Angle, (degree)
cmo / addatt / MO_NAME / ang_maxd / a_maxd
* Maximum Dihedral Angle, (radian)
cmo / addatt / MO_NAME / ang_maxr / a_maxr
* Minimum Solid Angle, (degree)
cmo / addatt / MO_NAME / ang_mind_solid / s_mind
* Minimum Solid Angle, (radian)
cmo / addatt / MO_NAME / ang_minr_solid / s_minr
* Maximum Solid Angle, (degree)
cmo / addatt / MO_NAME / ang_maxd_solid / s_maxd
* Maximum Solid Angle, (radian)
cmo / addatt / MO_NAME / ang_maxr_solid / s_maxr
* Aspect Ratio
quality / aspect / y
* ( minimum edge lenght ) / ( maximum edge length )
quality / edge_ratio / y
* Edge lenght minimum
quality / edge_min / y
* Edge length maximum
quality / edge_max / y
*
* Identify Slivers
*
* Define adjustable parameters to determine cut-off values.
*
define / MIN_DIHEDRAL  /  10.0
define / MAX_DIHEDRAL  / 170.0
define / MAX_SOLID_ANG_BIG / 170.0
define / MAX_SOLID_ANG_SMALL / 10.0
define / EDGE_RATIO    /   0.1
*
eltset / e_dih_small / a_mind / le / MIN_DIHEDRAL
eltset / e_dih_big   / a_maxd / ge / MAX_DIHEDRAL
eltset / e_solid_big / s_maxd   / le / MAX_SOLID_ANG_SMALL
eltset / e_tmp       / inter / e_dih_small e_dih_big
eltset / e_sliver    / inter / &
         e_tmp e_solid_big
*
* Identify Cap elements
*
eltset / e_cap / s_maxd / ge / MAX_SOLID_ANG_BIG
*
* Identify Needle elements
*
eltset / e_edge_ratio / eratio   / le / EDGE_RATIO
eltset / e_dih_small  / a_mind / le / MIN_DIHEDRAL
eltset / e_needle / not / e_edge_ratio e_dih_small
*
* Identify Wedge elements
*
eltset / e_wedge / inter / e_edge_ratio e_dih_small
*
* Set up some attributes to tag the elements.
*
cmo/addatt/MO_NAME/if_sliv/vint/scalar/nelements/-def-/-def-/-def-/1
cmo/addatt/MO_NAME/if_cap/vint/scalar/nelements/-def-/-def-/-def-/1
cmo/addatt/MO_NAME/if_ned/vint/scalar/nelements/-def-/-def-/-def-/1
cmo/addatt/MO_NAME/if_wed/vint/scalar/nelements/-def-/-def-/-def-/1

cmo/setatt/MO_NAME/if_sliv/ 1 0 0 / 1
cmo/setatt/MO_NAME/if_cap / 1 0 0 / 1
cmo/setatt/MO_NAME/if_ned / 1 0 0 / 1
cmo/setatt/MO_NAME/if_wed / 1 0 0 / 1

cmo/setatt/MO_NAME/if_sliv/eltset get e_sliver/ 2
cmo/setatt/MO_NAME/if_cap /eltset get e_cap   / 2
cmo/setatt/MO_NAME/if_ned /eltset get e_needle/ 2
cmo/setatt/MO_NAME/if_wed /eltset get e_wedge / 2

eltset / e_dih_small / delete
eltset / e_dih_big / delete
eltset / e_solid_big / delete
eltset / e_tmp / delete
eltset / e_sliver / delete
eltset / e_cap / delete
eltset / e_edge_ratio / delete
eltset / e_needle / delete
eltset / e_wedge / delete

finish