*--* ex_addmesh_add
*--* Header Begin
*--* LAGriT Example Input file
* Carl Gable
* gable -at- lanl -dot- gov
*
*
*--* Create a rough and fine mesh,
*--* Insert the fine mesh inside the course mesh,
*--* Refine the course mesh near the fine mesh,
*--* Delete elements of the course mesh that intersect the fine mesh
*--* Put the two MO into a single MO
*--* Copy the point distribution into a tet MO
*--* Connect the points to a Delaunay mesh
*--*
*--*----------------------------------------------------
*--* Header End
*--* ex_addmesh_add
*--*
* Create the larger mesh
*
cmo / create / cmo_hex / / / hex
cmo / select / cmo_hex
*
* Create a simple hex mesh, NX-NY-NZ
define / NX / 10
define / NY / 10
define / NZ / 10
createpts/brick/xyz/NX,NY,NZ/0.,0.,0./1.,1.,1./1,1,1
*
* Set the element material id numbers (itetclr) to 1
cmo / setatt / cmo_hex / itetclr / 1 0 0 / 1
*
* Set the node material id numbers (imt) to 1
cmo / setatt / cmo_hex / imt / 1 0 0 / 1
*
* Set the point types (interior => itp=2  exterior itp=10)
*
resetpts / itp
*
* Convert hex mesh object to a tet mesh object
*
hextotet / 5 / cmo_tet1 / cmo_hex
quality
*
* Create the smaller mesh which will have higher resolution
*
cmo / create / cmo_hex2 / / / hex
cmo / select / cmo_hex2
define / NX / 10
define / NY / 10
define / NZ / 30
createpts/brick/xyz/NX,NY,NZ/0.4, 0.4, 0.1/ 0.6 0.6 0.9 /1,1,1
cmo / setatt / cmo_hex2 / itetclr / 1 0 0 / 1
cmo / setatt / cmo_hex2 / imt / 1 0 0 / 1
resetpts / itp
hextotet / 5 / cmo_tet2 / cmo_hex2
quality
*
* Insert the small mesh into the large
*
*This will excavate the cmo_tet1 mesh to make room for the cmo_tet2 mesh
*
addmesh / add / cmo_add / cmo_tet1 / cmo_tet2
*
* Turn off polygon output
*
cmo/setatt//ipolydat/no
dump / gmv / addmesh.gmv / cmo_add

cmo / create / cmo_tet3 / / / tet
copypts / cmo_tet3 / cmo_add
cmo / setatt / cmo_tet3 / imt / 1 0 0 / 1
cmo / setatt / cmo_tet3 / itp / 1 0 0 / 0

connect
resetpts / itp
quality

cmo/setatt//ipolydat/no
dump / gmv / connect.gmv / cmo_tet3

finish