*--* ex_intersect_surface_line
*--* Header Begin
*--* LAGriT Example Input file
* Carl Gable
* gable -at- lanl -dot- gov
*
*
*--* Create two xy quadrilateral mesh
*--* Use MATH function to set z coordinate of mesh to sin(x) and sin(y)
*--* Create a line type mesh object which is the geometric intersection
*--* of the two quad meshes.
*--*
*--*----------------------------------------------------
*--* Header End
*--* ex_intersect_surface_line
*--*
*
* Define parameter to be used later.
*
define/NX/50
define/NY/50
define/MIN/0.0                                                                  
define/MAX/10.0
*
* Create the quad surfaces
*
cmo/create/cmo_1///quad                                                         
quadxy NX NY/MIN MIN 0./MAX MIN 0./MAX MAX 0./MIN MAX 0.
rzbrick/xyz/NX,NY,1/1,0,0/connect
*
* Copy the quad surface into another mesh object
*
cmo/copy/cmo_2/cmo_1 
*
cmo / setatt / cmo_1 / itetclr / 1 0 0 / 1
cmo / setatt / cmo_2 / itetclr / 1 0 0 / 2
*
* Use the math command to set the z coordinates to:
*
* cmo_1   z(i)=sin(y(i))
* cmo_2   z(i)=sin(x(i))
*
math/sin/cmo_1/zic/1,0,0/cmo_1/yic
math/sin/cmo_2/zic/1,0,0/cmo_2/xic                                              
cmo / select / cmo_1
cmo/setatt//ipolydat/no
cmo / select / cmo_2
cmo/setatt//ipolydat/no
dump / gmv / z_sin_y.gmv / cmo_1
dump / gmv / z_sin_x.gmv / cmo_2

addmesh / append / cmo_all / cmo_1 / cmo_2
cmo/setatt//ipolydat/no
dump / gmv / sin_x_sin_y.gmv / cmo_all
cmo / delete / cmo_all
*
intersect / cmo_line / cmo_1 / cmo_2

dump / gmv / line.gmv / cmo_line

finish